ASC2.0 のインライン化機能 （新しい ActionScript コンパイラの変更点つづき）

通常のコーディング時にはそれほど神経質になる必要は無いと思いますが、ループ内の関数呼び出し等では、インライン化の有無により大きく差が出ることもありるかもしれません。

なので、チューニングの手段の 1 つとして覚えておいても良いかもです。（といっても、ASC 2.0 はまだベータ版なのですが）

インライン化される関数されない関数

関数をインライン化するかしないかは ASC 2.0 の判断です。その際の判断基準となる条件がいくつかあります。

まず、final や static の修飾子がついた関数は、インライン化の候補となります。ファイル内、あるいはパッケージ内からしか参照できない関数も候補です。

たとえば、

final public function get foo():int
{
  return _foo;
}

の様にして、ゲッターやセッターをインライン化させるのは良いアイデアかも知れません。

Inline メタデータを指定してもよいようです。

[Inline]
final public function bar(i:int):int
{
  var sum:int = i + _foo;
  return sum;
}

しかし、インライン化の対象の関数でも、try を含む場合はインライン化されないようです。

[Inline]
static public function baz(i:int):Number
{
  try // この記述があるとインライン化されない
  {
    return i / _foo;
  }
  catch (e:Error)
  {
    return 0.0;
  }
}

同様に、with を含む関数も対象外となるようです。

また、サブクラスやインターフェース経由での呼び出しもインライン化されないようです。

public interface MyInterface
{
  function bar(i:int):int
}
 
public class MyClass implements MyInterface
{
  private var _foo:int = 0;
 
  [Inline]
  final public function bar(i:int):int
  {
    var sum:int = i + _foo;
    return sum;
  }
}
 
var mc:MyClass = new MyClass();
mc.bar(0); // インライン化される
 
var mi:MyInterface = mc;
mi.bar(0); // インライン化されない

その他、含まれる式の数が 50 を超えるとインライン化されないという制限もあるようです。