Flash Player 10.1　のエラー処理機能 （グローバルエラー編）

ともあれ、これらのオブジェクトにイベントハンドラーを追加すればよいわけです

LoaderInfo に UncaughtErrorEvent イベントハンドラーを追加するときは、コンストラクタ内で行うのがよいと思われます。

import flash.events.UncaughtErrorEvent;
 
public class UncaughtErrorEventExample extends Sprite
{
  public function UncaughtErrorEventExample()
  {
    loaderInfo.uncaughtErrorEvents.addEventListener(
        UncaughtErrorEvent.UNCAUGHT_ERROR, onUncaughtError);
  }
 
  private function onUncaughtError(event:UncaughtErrorEvent):void
  {
    // エラー処理を記述 
  }
}
 

Flex の場合は、ApplicationComplete イベントのタイミングで追加する、という感じでしょうか。

<s:WindowedApplication xmlns:fx="http://ns.adobe.com/mxml/2009" 
                       applicationComplete="onApplicationComplete();">
  <fx:Script>
    <![CDATA[
      import flash.events.UncaughtErrorEvent;
            
      private function onApplicationComplete():void
      {
        loaderInfo.uncaughtErrorEvents.addEventListener(
            UncaughtErrorEvent.UNCAUGHT_ERROR, onUncaughtError);
      }
 
      private function onUncaughtError(event:UncaughtErrorEvent):void
      {
        // エラー処理を記述 
      }
    ]]>
  </fx:Script>
</s:WindowedApplication>
 

イベントハンドラーの書き方についてですが、

UncaughtErrorEvent には error という属性があり、ここに未処理のエラーオブジェクト、すなわち Error オブジェクト （同期エラーの場合） や ErrorEvent オブジェクト （非同期エラーの場合） が設定されます。

ただし、以前の記事にも書いたように、スクリプトから任意の型のオブジェクトを throw することが可能です。なので、UncaughtErrorEvent のハンドラーでは、Error、ErrorEvent、それ以外、の 3 種類の （最低でも） オブジェクトを扱えるようにします。

function onUncaughtError(event:UncaughtErrorEvent):void
{
  var message:String;
 
  if (event.error is Error)
  {
    message = Error(event.error).message;
  }
  else if (event.error is ErrorEvent)
  {
    message = ErrorEvent(event.error).text;
  }
  else
  {
    message = event.error.toString();
  }
}
 

8/11 追記： ステータスイベントによるエラー通知 （NetStatusEvent.info.level や StatusEvent.level の値が error） の場合には、エラーが未処理でも UncaughtErrorEvent がディスパッチされません。イベントハンドラー内に、ステータスイベントを扱うための記述は不要です。

Loader に読み込んだ外部 SWF のグローバルエラーハンドラー使用については、次回に続きます。